include_directories(${CMAKE_CURRENT_SOURCE_DIR} ./../Runtime)
add_subdirectory(locale)
add_subdirectory(icons)

if("${CMAKE_BUILD_TYPE}" STREQUAL "Release")
  option(RUDE_BINARY_CONFIGS
         "Use binary Athena formats for serializing save data structures, rather than YAML"
         YES)
else()
  option(RUDE_BINARY_CONFIGS
         "Use binary Athena formats for serializing save data structures, rather than YAML"
         NO)
endif()

if(RUDE_BINARY_CONFIGS)
  add_definitions("-DURDE_BINARY_CONFIGS=1")
endif()

atdna(atdna_Space.cpp Space.hpp)
atdna(atdna_ResourceBrowser.cpp ResourceBrowser.hpp)
atdna(atdna_ModelViewer.cpp ModelViewer.hpp)
atdna(atdna_ParticleEditor.cpp ParticleEditor.hpp)
atdna(atdna_InformationCenter.cpp InformationCenter.hpp)

if(WIN32)
  set(PLAT_SRCS platforms/win/urde.rc)
elseif(APPLE)
  set(PLAT_SRCS platforms/mac/mainicon.icns)
  set_source_files_properties(platforms/mac/mainicon.icns PROPERTIES
                              MACOSX_PACKAGE_LOCATION Resources)
elseif(UNIX)
  add_subdirectory(platforms/freedesktop)
  declare_wmicon_target()
  set(PLAT_SRCS mainicon_netwm.c)
endif()

add_executable(urde WIN32 MACOSX_BUNDLE
               main.cpp ${PLAT_SRCS}
               Space.hpp Space.cpp atdna_Space.cpp
               SplashScreen.hpp SplashScreen.cpp
               ResourceBrowser.hpp ResourceBrowser.cpp atdna_ResourceBrowser.cpp
               ModelViewer.hpp ModelViewer.cpp atdna_ModelViewer.cpp
               ParticleEditor.hpp ParticleEditor.cpp atdna_ParticleEditor.cpp
               InformationCenter.hpp InformationCenter.hpp atdna_InformationCenter.cpp
               ProjectManager.hpp ProjectManager.cpp
               ProjectResourceFactory.hpp ProjectResourceFactory.cpp
               ViewManager.hpp ViewManager.cpp
               Resource.hpp Resource.cpp
               Camera.hpp Camera.cpp)

target_link_libraries(urde
                      UrdeLocales
                      UrdeIcons
                      RuntimeCommonCharacter
                      RuntimeCommonInput
                      RuntimeCommonParticle
                      RuntimeCommonGraphics
                      RuntimeCommon
                      DNAMP3 DNAMP2 DNAMP1
                      DNACommon Specter SpecterFonts freetype ${DATA_SPEC_LIBS}
                      HECLDatabase HECLBackend HECLFrontend HECLBlender HECLRuntime HECLCommon AthenaCore NOD
                      LogVisor AthenaLibYaml Boo ${PNG_LIB} squish xxhash Math
                      ${ZLIB_LIBRARIES} ${LZO_LIB}
                      ${BOO_SYS_LIBS})

set_target_properties(urde PROPERTIES
                      MACOSX_BUNDLE_INFO_PLIST "${CMAKE_CURRENT_SOURCE_DIR}/platforms/mac/Info.plist")