mirror of
https://github.com/encounter/dawn-cmake.git
synced 2025-07-14 00:56:05 +00:00
This PR fixes one gn include issue and widens the GN check results to test all but one of the GN targets. The remaining target is disabled due to our absl configuration. Bug: dawn:1372 Change-Id: I6e92a7aa777c3508e57d1e7138c73b7a92756db1 Reviewed-on: https://dawn-review.googlesource.com/c/dawn/+/88680 Reviewed-by: Brandon Jones <bajones@chromium.org> Kokoro: Kokoro <noreply+kokoro@google.com> Reviewed-by: Ben Clayton <bclayton@google.com> Commit-Queue: Dan Sinclair <dsinclair@chromium.org>
79 lines
2.0 KiB
Plaintext
79 lines
2.0 KiB
Plaintext
# Copyright 2020 The Dawn Authors
|
|
#
|
|
# Licensed under the Apache License, Version 2.0 (the "License");
|
|
# you may not use this file except in compliance with the License.
|
|
# You may obtain a copy of the License at
|
|
#
|
|
# http://www.apache.org/licenses/LICENSE-2.0
|
|
#
|
|
# Unless required by applicable law or agreed to in writing, software
|
|
# distributed under the License is distributed on an "AS IS" BASIS,
|
|
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
|
|
# See the License for the specific language governing permissions and
|
|
# limitations under the License.
|
|
|
|
import("../../../scripts/dawn_overrides_with_defaults.gni")
|
|
|
|
group("samples") {
|
|
deps = [
|
|
":Animometer",
|
|
":CHelloTriangle",
|
|
":ComputeBoids",
|
|
":CppHelloTriangle",
|
|
":ManualSwapChainTest",
|
|
]
|
|
}
|
|
|
|
# Static library to contain code and dependencies common to all samples
|
|
static_library("utils") {
|
|
sources = [
|
|
"SampleUtils.cpp",
|
|
"SampleUtils.h",
|
|
]
|
|
|
|
# Export all of these as public deps so that `gn check` allows includes
|
|
public_deps = [
|
|
"${dawn_root}/src/dawn:cpp",
|
|
"${dawn_root}/src/dawn:proc_shared",
|
|
"${dawn_root}/src/dawn/common",
|
|
"${dawn_root}/src/dawn/native",
|
|
"${dawn_root}/src/dawn/utils",
|
|
"${dawn_root}/src/dawn/utils:bindings",
|
|
"${dawn_root}/src/dawn/utils:glfw",
|
|
"${dawn_root}/src/dawn/wire",
|
|
]
|
|
public_configs = [ "${dawn_root}/src/dawn/common:internal_config" ]
|
|
}
|
|
|
|
# Template for samples to avoid listing utils as a dep every time
|
|
template("sample") {
|
|
executable(target_name) {
|
|
deps = [ ":utils" ]
|
|
forward_variables_from(invoker, "*", [ "deps" ])
|
|
|
|
if (defined(invoker.deps)) {
|
|
deps += invoker.deps
|
|
}
|
|
}
|
|
}
|
|
|
|
sample("CppHelloTriangle") {
|
|
sources = [ "CppHelloTriangle.cpp" ]
|
|
}
|
|
|
|
sample("CHelloTriangle") {
|
|
sources = [ "CHelloTriangle.cpp" ]
|
|
}
|
|
|
|
sample("ComputeBoids") {
|
|
sources = [ "ComputeBoids.cpp" ]
|
|
}
|
|
|
|
sample("Animometer") {
|
|
sources = [ "Animometer.cpp" ]
|
|
}
|
|
|
|
sample("ManualSwapChainTest") {
|
|
sources = [ "ManualSwapChainTest.cpp" ]
|
|
}
|